From 37da2899f40661e3e9631e497da8dc59b971cbd0 Mon Sep 17 00:00:00 2001
From: "Charles.Forsyth" <devnull@localhost>
Date: Fri, 22 Dec 2006 17:07:39 +0000
Subject: 20060303a

---
 libkern/memmove-386.s | 58 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 libkern/memmove-386.s

(limited to 'libkern/memmove-386.s')

diff --git a/libkern/memmove-386.s b/libkern/memmove-386.s
new file mode 100644
index 00000000..e85bb232
--- /dev/null
+++ b/libkern/memmove-386.s
@@ -0,0 +1,58 @@
+	TEXT	memmove(SB), $0
+	TEXT	memcpy(SB), $0
+
+	MOVL	p1+0(FP), DI
+	MOVL	p2+4(FP), SI
+	MOVL	n+8(FP), BX
+	CMPL	BX, $0
+	JGE	ok
+	MOVL	$0, SI
+ok:
+	CLD
+/*
+ * check and set for backwards
+ */
+	CMPL	SI, DI
+	JLS	back
+/*
+ * copy whole longs
+ */
+	MOVL	BX, CX
+	SHRL	$2, CX
+	REP;	MOVSL
+/*
+ * copy the rest, by bytes
+ */
+	ANDL	$3, BX
+	MOVL	BX, CX
+	REP;	MOVSB
+
+	MOVL	p+0(FP),AX
+	RET
+/*
+ * whole thing backwards has
+ * adjusted addresses
+ */
+back:
+	ADDL	BX, DI
+	ADDL	BX, SI
+	SUBL	$4, DI
+	SUBL	$4, SI
+	STD
+/*
+ * copy whole longs
+ */
+	MOVL	BX, CX
+	SHRL	$2, CX
+	ANDL	$3, BX
+	REP;	MOVSL
+/*
+ * copy the rest, by bytes
+ */
+	ADDL	$3, DI
+	ADDL	$3, SI
+	MOVL	BX, CX
+	REP;	MOVSB
+
+	MOVL	p+0(FP),AX
+	RET
-- 
cgit v1.2.3