2 files changed, 128 insertions, 0 deletions
diff --git a/appl/collab/lib/messages.b b/appl/collab/lib/messages.b
new file mode 100644
index 00000000..ab982339
--- /dev/null
+++ b/appl/collab/lib/messages.b
@@ -0,0 +1,86 @@
+implement Messages;
+
+#
+# message queues and their users
+#
+
+include "messages.m";
+
+clientidgen := 1;
+
+init()
+{
+	clientidgen = 1;
+}
+
+Msglist.new(): ref Msglist
+{
+	msgs := ref Msglist;
+	msgs.tail = ref Msg;	# valid Msg when .next != nil
+	return msgs;
+}
+
+Msglist.queue(msgs: self ref Msglist): ref Msg
+{
+	return msgs.tail;
+}
+
+Msglist.wait(msgs: self ref Msglist, u: ref User, rd: ref Readreq)
+{
+	msgs.readers = (u, rd) :: msgs.readers;	# list reversed, but currently does not matter
+}
+
+Msglist.write(msgs: self ref Msglist, m: ref Msg): list of (ref User, ref Readreq)
+{
+	tail := msgs.tail;
+	tail.from = m.from;
+	tail.data = m.data;
+	tail.next = ref Msg(nil, nil, nil);
+	msgs.tail = tail.next;	# next message will be formed in tail.next
+	rl := msgs.readers;
+	msgs.readers = nil;
+	return rl;
+}
+
+Msglist.flushtag(msgs: self ref Msglist, tag: int)
+{
+	rl := msgs.readers;
+	msgs.readers = nil;
+	for(; rl != nil; rl = tl rl){
+		(nil, req) := hd rl;
+		if(req.tag != tag)
+			msgs.readers = hd rl :: msgs.readers;
+	}
+}
+
+Msglist.flushfid(msgs: self ref Msglist, fid: int)
+{
+	rl := msgs.readers;
+	msgs.readers = nil;
+	for(; rl != nil; rl = tl rl){
+		(nil, req) := hd rl;
+		if(req.fid != fid)
+			msgs.readers = hd rl :: msgs.readers;
+	}
+}
+
+User.new(fid: int, name: string): ref User
+{
+	return ref User(clientidgen++, fid, name, nil);
+}
+
+User.initqueue(u: self ref User, msgs: ref Msglist)
+{
+	u.queue = msgs.tail;
+}
+
+User.read(u: self ref User): ref Msg
+{
+	if((m := u.queue).next != nil){
+		u.queue = m.next;
+		m = ref *m;	# copy to ensure no aliasing
+		m.next = nil;
+		return m;
+	}
+	return nil;
+}
diff --git a/appl/collab/lib/messages.m b/appl/collab/lib/messages.m
new file mode 100644
index 00000000..ab1c679a
--- /dev/null
+++ b/appl/collab/lib/messages.m
@@ -0,0 +1,42 @@
+Messages:  module
+{
+	PATH:	con "/dis/collab/lib/messages.dis";
+
+	Msg: adt {
+		from:	cyclic ref User;
+		data:		array of byte;
+		next:		cyclic ref Msg;
+	};
+
+	Msglist: adt {
+		tail:		ref Msg;
+		readers:	list of (ref User, ref Readreq);
+
+		new:		fn(): ref Msglist;
+		flushfid:	fn(nil: self ref Msglist, fid: int);
+		flushtag:	fn(nil: self ref Msglist, tag: int);
+		wait:		fn(nil: self ref Msglist, u: ref User, r: ref Readreq);
+		write:	fn(nil: self ref Msglist, m: ref Msg): list of (ref User, ref Readreq);
+		queue:	fn(nil: self ref Msglist): ref Msg;
+	};
+
+	Readreq: adt {
+		tag:	int;
+		fid:	int;
+		count:	int;
+		offset:	big;
+	};
+
+	User: adt {
+		id:	int;
+		fid:	int;
+		name:	string;
+		queue:	cyclic ref Msg;
+
+		new:	fn(fid: int, name: string): ref User;
+		initqueue:	fn(nil: self ref User, msgs: ref Msglist);
+		read:	fn(nil: self ref User): ref Msg;
+	};
+
+	init:	fn();
+};